This script is used to shutdown the computer while performing several task.

Download Shutdown (vbs file)

  1. ' ********************************************************
  2. ' FILE: ShutdownScript.vbs
  3. ' VERSION: 1.1
  4. ' CREATED: 3/21/2004
  5. ' UPDATED:   6/28/2004
  6. ' AUTHOR:    Scott Greenberg
  7. ' COMPANY:   SG Technology
  8. ' WEBSITE: http://gogogadgetscott.info
  9. ' DECRIPTION:
  10. ' COMMENT: N/A
  11. ' Copyright© 2004. SG Technology. All rights reserved.
  12. ' *********************************************************
  14. Set SH = CreateObject ("WScript.Shell")
  15. Set FS = CreateObject ("Scripting.FileSystemObject")
  17. CreateSC
  18. RemoveRegKey "AIM"
  19. RemoveRegKey "TkBellExe"
  20. RemoveRegKey "NvCplDaemon"
  21. RemoveRegKey "StarSkin"
  22. ShutdownOutlook
  23. 'EmptyBin
  24. Shutdown
  26. Set Shell = Nothing
  27. Set SH = Nothing
  28. Set FS = Nothing
  29. WScript.Quit
  31. Function ScriptPath
  32.   sPath = WScript.ScriptFullName
  33.   ScriptPath = Left (sPath,InStrRev (sPath,"\"))
  34. End Function
  36. '==========================================================
  37. ' Create desktop shortcut To script
  38. '==========================================================
  39. Sub CreateSC()
  40.   sDesktop = SH.SpecialFolders("Desktop")
  41.   Set oSC = SH.CreateShortcut(sDesktop & "\ShutdownScript.lnk")
  42.   oSC.TargetPath = WScript.ScriptFullName
  43.   oSC.WindowStyle = 1
  44.   oSC.Hotkey = "CTRL+ALT+D"
  45.   oSC.IconLocation = "shell32.dll, 27"
  46.   'oSC.IconLocation = "explorer.exe, 0"
  47.   oSC.Description = "Shutdown Computer Script"
  48.   oSC.WorkingDirectory = sDesktop
  49.   oSC.Save
  50. End Sub
  52. '==========================================================
  53. ' Backup Windows registry
  54. '==========================================================
  55. Sub BackupReg()
  56.   ' Needs Fix For windows XP
  57.   Const FILE_BackupReg = "backupreg.bat"
  58.   Set fBat = FS.CreateTextFile(FILE_BackupReg, True )
  59.   fBat.WriteLine "cd\windows"
  60.   fBat.WriteLine "attrib -s -h -r *.dat"
  61.   fBat.WriteLine "copy user.dat user.sav"
  62.   fBat.WriteLine "copy system.dat system.sav"
  63.   Set fBat = Nothing
  64.   SH.Run FILE_BackupReg, 0, True
  65. End Sub
  67. '==========================================================
  68. ' Remove unwanted startup registry key from machine And user
  69. '==========================================================
  70. Sub RemoveRegKey(sKey)
  71.   sKey = "\Software\Microsoft\Windows\CurrentVersion\Run\" & sKey
  72.   On Error Resume Next
  73.   SH.RegDelete "HKCU" & sKey
  74.   SH.RegDelete "HKLM" & sKey
  75. End Sub
  77. '==========================================================
  78. ' Empty the recycle bin
  79. '==========================================================
  80. Sub EmptyBin()
  81.   Set fEBin = FS.CreateTextFile(ScriptPath & "Tmp_EBin.vbs",2)
  82.   fEBin.writeline "Set FS = CreateObject (""Scripting.FileSystemObject"")"
  83.   fEBin.writeline "Set Shell = CreateObject (""Shell.Application"")"
  84.   fEBin.writeline "Set oFolder = FS.GetFolder(""C:\RECYCLER"")"
  85.   fEBin.writeline "If (Not oFolder Is Nothing ) Then "
  86.   fEBin.writeline "   For Each oFldr In oFolder.SubFolders"
  87.   fEBin.writeline " Set oNS = Shell.NameSpace(oFldr.Path)"
  88.   fEBin.writeline " If (Not oFolder Is Nothing ) Then "
  89.   fEBin.writeline "   oNS.Self.InvokeVerb(""Empty Recycle &Bin"")"
  90.   fEBin.writeline "   Set oNS = Nothing "
  91.   fEBin.writeline "   Exit For "
  92.   fEBin.writeline " End If "
  93.   fEBin.writeline " Next "
  94.   fEBin.writeline " Set oFolder = Nothing "
  95.   fEBin.writeline "End If "
  96.   fEBin.writeline "Set FS = Nothing "
  97.   fEBin.writeline "Set Shell = Nothing "
  98.   fEBin.close
  99.   iReturn = SH.Run("""" & ScriptPath & "Tmp_EBin.vbs""", 1, False )
  100.   WScript.Sleep 650
  101.   iReturn = SH.AppActivate("Confirm Multiple File Delete")
  102.   If iReturn = False Then
  103.     iReturn = SH.AppActivate("Confirm File Delete")
  104.   End If
  105.   If iReturn = True Then
  106.     SH.SendKeys("{ENTER}")
  107.   End If
  108.   ' Delete temp file
  109.   FS.DeleteFile ScriptPath & "Tmp_EBin.vbs"
  110. End Sub
  112. '==========================================================
  113. ' Shutdown Microsoft Outlook, only needed For Outlook XP,
  114. ' As other versions will close properly at a windows
  115. ' invoked Shellutdown
  116. '==========================================================
  117. Sub ShutdownOutlook()
  118.   Set olApp = CreateObject ("Outlook.Application")
  119.   olApp.Quit()
  120.   Set olApp = Nothing
  121. End Sub
  123. '==========================================================
  124. ' Shutdown computer
  125. '==========================================================
  126. Sub Shutdown()
  127.   SH.Run "shutdown -s -t 1", 0, True
  128. End Sub

Download Shutdown (vbs file)